Natives and forwards

// native void MyPlugin_Greet(const char[] name, char[] out, int maxlen);
public any Native_Greet(Handle plugin, int numParams)
{
	char name[64], out[128];
	Source2ModNatives.GetString(1, name, sizeof(name));
	Source2ModApi.Format(out, sizeof(out), "Hello, %s!", name);
	Source2ModNatives.SetString(2, out, Source2ModNatives.GetCell(3));
	return 0;
}

// native void MyPlugin_Double(int &value, int values[3]);
public any Native_Double(Handle plugin, int numParams)
{
	Source2ModNatives.SetCellRef(1, Source2ModNatives.GetCellRef(1) * 2);

	int values[3];
	Source2ModNatives.GetArray(2, values, sizeof(values));
	for (int i = 0; i < sizeof(values); i++)
		values[i] *= 2;
	Source2ModNatives.SetArray(2, values, sizeof(values));
	return 0;
}

// native void MyPlugin_SetPoints(CPlayerSlot slot, int points);
public any Native_SetPoints(Handle plugin, int numParams)
{
	CPlayerSlot slot = Source2ModNatives.GetCell(1);
	if (!slot.IsValid())
		return Source2ModNatives.ThrowError(SP_ERROR_NATIVE, "Invalid player slot %d", slot.Get());

	// ...
	return 0;
}

#if defined _sample_included
 #endinput
#endif
#define _sample_included

/** a + b. */
native int Sample_Add(int a, int b);

/** Formats into buffer. @return Bytes written */
native int Sample_Echo(char[] buffer, int maxlen, const char[] fmt, any ...);

public SharedPlugin __pl_sample =
{
	name = "sample",
	file = "sample.smx",
	required = 0,
};

#if !defined REQUIRE_PLUGIN
public void __pl_sample_SetNTVOptional()
{
	MarkNativeAsOptional("Sample_Add");
	MarkNativeAsOptional("Sample_Echo");
}
#endif

#include <source2mod/api>

#undef REQUIRE_PLUGIN
#include <sample>

bool g_hasSample;

public void OnPluginStart()
{
	g_hasSample = Source2ModNatives.LibraryExists("sample");
	Source2ModCommands.RegisterConCommand("add", Cmd_Add);
}

public void OnLibraryAdded(const char[] name)
{
	if (Source2ModUtils.Equal(name, "sample"))
		g_hasSample = true;
}

public void OnLibraryRemoved(const char[] name)
{
	if (Source2ModUtils.Equal(name, "sample"))
		g_hasSample = false;
}

public void Cmd_Add(Source2ModCommandContext context, Source2ModCommandArgs args, bool post)
{
	if (!g_hasSample)
	{
		Source2ModCommands.ReplyToCommand(context, "The sample plugin is not loaded.");
		return;
	}

	char text[64];
	Sample_Echo(text, sizeof(text), "2 + 3 = %d", Sample_Add(2, 3));
	Source2ModCommands.ReplyToCommand(context, "%s", text);
}

GlobalForward g_fwdOnPoints;

public void OnPluginStart()
{
	// forward Action MyPlugin_OnPoints(CPlayerSlot slot, int &points);
	g_fwdOnPoints = new GlobalForward("MyPlugin_OnPoints", ET_Hook, Param_Cell, Param_CellByRef);
}

// Asks every plugin first; false when one of them blocked it.
bool GivePoints(CPlayerSlot slot, int points)
{
	Action result = Plugin_Continue;
	Source2ModCall.StartForward(g_fwdOnPoints);
	Source2ModCall.PushCell(slot);
	Source2ModCall.PushCellRef(points);
	if (Source2ModCall.Finish(result) != SP_ERROR_NONE || result >= Plugin_Handled)
		return false;

	// ... give `points` -- changed when a plugin answered Plugin_Changed
	return true;
}

public Action MyPlugin_OnPoints(CPlayerSlot slot, int &points)
{
	if (points > 100)
		return Plugin_Handled;      // blocked

	points *= 2;
	return Plugin_Changed;
}

PrivateForward g_fwdRoundWon;

public APLRes AskPluginLoad2(Handle myself, bool late, char[] error, int err_max)
{
	// native void MyPlugin_OnRoundWon(MyPlugin_RoundWonCallback callback);
	Source2ModNatives.CreateNative("MyPlugin_OnRoundWon", Native_OnRoundWon);
	return APLRes_Success;
}

public void OnPluginStart()
{
	// typedef MyPlugin_RoundWonCallback = function void (int team);
	g_fwdRoundWon = new PrivateForward(ET_Ignore, Param_Cell);
}

public any Native_OnRoundWon(Handle plugin, int numParams)
{
	g_fwdRoundWon.AddFunction(plugin, Source2ModNatives.GetFunction(1));
	return 0;
}

void RoundWon(int team)
{
	Source2ModCall.StartForward(g_fwdRoundWon);
	Source2ModCall.PushCell(team);
	Source2ModCall.Finish();
}

public int Tripled(int value)
{
	return value * 3;
}

public void OnPluginStart()
{
	Function fn = Source2ModCall.GetFunctionByName(INVALID_HANDLE, "Tripled");

	int result;
	Source2ModCall.StartFunction(INVALID_HANDLE, fn);
	Source2ModCall.PushCell(5);
	if (Source2ModCall.Finish(result) == SP_ERROR_NONE)
		Source2ModApi.Log("Tripled(5) = %d", result);
}